mirror of
https://github.com/tbamud/tbamud.git
synced 2026-02-26 13:31:45 +01:00
Setting up 3.5.0 as trunk
This commit is contained in:
Rumble
234
lib/world/trg/30.trg
Normal file
234
lib/world/trg/30.trg
Normal file
@@ -0,0 +1,234 @@
|
||||
#3000
|
||||
Mage Guildguard - 3024~
|
||||
0 q 100
|
||||
~
|
||||
* Check the direction the player must go to enter the guild.
|
||||
if %direction% == south
|
||||
* Stop them if they are not the appropriate class.
|
||||
if %actor.class% != Magic User
|
||||
return 0
|
||||
%send% %actor% The guard humiliates you, and blocks your way.
|
||||
%echoaround% %actor% The guard humiliates %actor.name%, and blocks %actor.hisher% way.
|
||||
end
|
||||
end
|
||||
~
|
||||
#3001
|
||||
Cleric Guildguard - 3025~
|
||||
0 q 100
|
||||
~
|
||||
* Check the direction the player must go to enter the guild.
|
||||
if %direction% == north
|
||||
* Stop them if they are not the appropriate class.
|
||||
if %actor.class% != Cleric
|
||||
return 0
|
||||
%send% %actor% The guard humiliates you, and blocks your way.
|
||||
%echoaround% %actor% The guard humiliates %actor.name%, and blocks %actor.hisher% way.
|
||||
end
|
||||
end
|
||||
~
|
||||
#3002
|
||||
Thief Guildguard - 3026~
|
||||
0 q 100
|
||||
~
|
||||
* Check the direction the player must go to enter the guild.
|
||||
if %direction% == east
|
||||
* Stop them if they are not the appropriate class.
|
||||
if %actor.class% != Thief
|
||||
return 0
|
||||
%send% %actor% The guard humiliates you, and blocks your way.
|
||||
%echoaround% %actor% The guard humiliates %actor.name%, and blocks %actor.hisher% way.
|
||||
end
|
||||
end
|
||||
~
|
||||
#3003
|
||||
Warrior Guildguard - 3027~
|
||||
0 q 100
|
||||
~
|
||||
* Check the direction the player must go to enter the guild.
|
||||
if %direction% == east
|
||||
* Stop them if they are not the appropriate class.
|
||||
if %actor.class% != Warrior
|
||||
return 0
|
||||
%send% %actor% The guard humiliates you, and blocks your way.
|
||||
%echoaround% %actor% The guard humiliates %actor.name%, and blocks %actor.hisher% way.
|
||||
end
|
||||
end
|
||||
~
|
||||
#3004
|
||||
Dump - 3030~
|
||||
2 h 100
|
||||
~
|
||||
%echo% %object.shortdesc% vanishes in a puff of smoke!
|
||||
%send% %actor% You are awarded for outstanding performance.
|
||||
%echoaround% %actor% %actor.name% has been awarded for being a good citizen.
|
||||
eval value %object.cost% / 10
|
||||
%purge% %object%
|
||||
if %value% > 50
|
||||
eval value 50
|
||||
elseif %value% < 1
|
||||
eval value 1
|
||||
end
|
||||
if %actor.level% < 3
|
||||
nop %actor.exp(%value%)%
|
||||
else
|
||||
nop %actor.gold(%value%)%
|
||||
end
|
||||
~
|
||||
#3005
|
||||
Stock Thief~
|
||||
0 b 10
|
||||
~
|
||||
set actor %random.char%
|
||||
if %actor%
|
||||
if %actor.is_pc% && %actor.gold%
|
||||
%send% %actor% You discover that %self.name% has %self.hisher% hands in your wallet.
|
||||
%echoaround% %actor% %self.name% tries to steal gold from %actor.name%.
|
||||
eval coins %actor.gold% * %random.10% / 100
|
||||
nop %actor.gold(-%coins%)
|
||||
nop %self.gold(%coins%)
|
||||
end
|
||||
end
|
||||
~
|
||||
#3006
|
||||
Stock Snake~
|
||||
0 k 10
|
||||
~
|
||||
%send% %actor% %self.name% bites you!
|
||||
%echoaround% %actor% %self.name% bites %actor.name%.
|
||||
dg_cast 'poison' %actor%
|
||||
~
|
||||
#3007
|
||||
Stock Magic User~
|
||||
0 k 10
|
||||
~
|
||||
switch %actor.level%
|
||||
case 1
|
||||
case 2
|
||||
case 3
|
||||
break
|
||||
case 4
|
||||
dg_cast 'magic missile' %actor%
|
||||
break
|
||||
case 5
|
||||
dg_cast 'chill touch' %actor%
|
||||
break
|
||||
case 6
|
||||
dg_cast 'burning hands' %actor%
|
||||
break
|
||||
case 7
|
||||
case 8
|
||||
dg_cast 'shocking grasp' %actor%
|
||||
break
|
||||
case 9
|
||||
case 10
|
||||
case 11
|
||||
dg_cast 'lightning bolt' %actor%
|
||||
break
|
||||
case 12
|
||||
dg_cast 'color spray' %actor%
|
||||
break
|
||||
case 13
|
||||
dg_cast 'energy drain' %actor%
|
||||
break
|
||||
case 14
|
||||
dg_cast 'curse' %actor%
|
||||
break
|
||||
case 15
|
||||
dg_cast 'poison' %actor%
|
||||
break
|
||||
case 16
|
||||
if %actor.align% > 0
|
||||
dg_cast 'dispel good' %actor%
|
||||
else
|
||||
dg_cast 'dispel evil' %actor%
|
||||
end
|
||||
break
|
||||
case 17
|
||||
case 18
|
||||
dg_cast 'call lightning' %actor%
|
||||
break
|
||||
case 19
|
||||
case 20
|
||||
case 21
|
||||
case 22
|
||||
dg_cast 'harm' %actor%
|
||||
break
|
||||
default
|
||||
dg_cast 'fireball' %actor%
|
||||
break
|
||||
done
|
||||
~
|
||||
#3008
|
||||
Death Trap~
|
||||
2 g 100
|
||||
~
|
||||
* Near Death Trap stuns actor
|
||||
eval stunned %actor.hitp%
|
||||
%damage% %actor% %stunned%
|
||||
%send% %actor% You are on the brink of life and death.
|
||||
%send% %actor% The Gods must favor you this day.
|
||||
~
|
||||
#3009
|
||||
Stock Cityguard - 3059, 60, 67~
|
||||
0 b 50
|
||||
~
|
||||
if !%self.fighting%
|
||||
set actor %random.char%
|
||||
if %actor%
|
||||
if %actor.is_killer%
|
||||
emote screams 'HEY!!! You're one of those PLAYER KILLERS!!!!!!'
|
||||
kill %actor.name%
|
||||
elseif %actor.is_thief%
|
||||
emote screams 'HEY!!! You're one of those PLAYER THIEVES!!!!!!'
|
||||
kill %actor.name%
|
||||
elseif %actor.cha% < 6
|
||||
%send% %actor% %self.name% spits in your face.
|
||||
%echoaround% %actor% %self.name% spits in %actor.name%'s face.
|
||||
end
|
||||
if %actor.fighting%
|
||||
eval victim %actor.fighting%
|
||||
if %actor.align% < %victim.align% && %victim.align% >= 0
|
||||
emote screams 'PROTECT THE INNOCENT! BANZAI! CHARGE! ARARARAGGGHH!'
|
||||
kill %actor.name%
|
||||
end
|
||||
end
|
||||
end
|
||||
end
|
||||
~
|
||||
#3010
|
||||
Stock Fido - 3062, 3066~
|
||||
0 b 100
|
||||
~
|
||||
eval inroom %self.room%
|
||||
eval item %inroom.contents%
|
||||
while %item%
|
||||
* Target the next item in room. In case it is devoured.
|
||||
set next_item %item.next_in_list%
|
||||
* Check for a corpse. Corpse on TBA is vnum 65535. Stock is -1.
|
||||
if %item.vnum% == 65535
|
||||
emote savagely devours a corpse.
|
||||
%purge% %item%
|
||||
end
|
||||
set item %next_item%
|
||||
* Loop back
|
||||
done
|
||||
~
|
||||
#3011
|
||||
Stock Janitor - 3061, 3068~
|
||||
0 b 100
|
||||
~
|
||||
eval inroom %self.room%
|
||||
eval item %inroom.contents%
|
||||
while %item%
|
||||
* Target the next item in room. In case it is picked up.
|
||||
set next_item %item.next_in_list%
|
||||
* TODO: if %item.wearflag(take)%
|
||||
* Check for fountains and expensive items.
|
||||
if %item.type% != FOUNTAIN && %item.cost% <= 15
|
||||
take %item.name%
|
||||
end
|
||||
set item %next_item%
|
||||
* Loop back
|
||||
done
|
||||
~
|
||||
$~
|
||||
Reference in New Issue
Block a user